echo off
title windows 7 无线热点设置 By:r00tshell www.r00tshell.cn
color 1E
:main
cls
echo.
echo. /-------------------------------
echo. ‖ windows 7 无线热点设置 ‖
echo. -------------------------------/
echo.
echo. 1 - 显示无线热点状态
echo. 2 - 打开无线热点
echo. 3 - 关闭无线热点
echo. 4 - 禁用无线热点
echo. 5 - 启用无线热点
echo. 6 - 更改无线热点参数（SSID/KEY）
echo. 0 - 退出
echo.--------------------------------------------------------------------------------
echo.1.将上面代码保存在记事本里，改名更改为.bat(随便写，比如：Win7_Wifi.bat)
echo.2.初次使用，运行bat,输入6
echo.3.打开“网络和共享中心”--“更改适配器设置”看看是不是多了一项，如果有多出的这一项“Microsoft Virtual WiFi Miniport Adapter”，那么说明你前边的设置是正确的。
echo.4.设置Internet连接共享：在“网络连接”窗口中，右键单击已连接到Internet的网络连接(一般是“本地连接”)，选择“属性”→“共享”，勾上“允许其他······连接(N)”并选择刚才新建的虚拟连接。
echo.5.到此，基本上可以使用其他设备连接wifi上网了！
echo.================================================================================
set input=
set /p input=请选择【输入序号,然后回车】：
if /i '%input%'=='1' goto main1
if /i '%input%'=='2' goto main2
if /i '%input%'=='3' goto main3
if /i '%input%'=='4' goto main4
if /i '%input%'=='5' goto main5
if /i '%input%'=='6' goto main6
if /i '%input%'=='0' goto end
cls
echo.
pause
goto main
:end
set ssid=
set key=
exit
:main1
cls
echo 系统当前无线热点状态
echo.
netsh wlan show hostednetwork
echo.
pause
goto main
:main2
cls
echo 打开无线热点
echo.
netsh wlan start hostednetwork
echo.
pause
goto main1
:main3
cls
echo 关闭无线热点
echo.
netsh wlan stop hostednetwork
echo.
pause
goto main1
:main4
cls
echo 禁用无线热点
echo.
netsh wlan set hostednetwork mode=disallow
echo.
pause
goto main1
:main5
cls
echo 启用无线热点
echo.
netsh wlan set hostednetwork mode=allow
pause
goto main2
:main6
cls
echo 更改无线热点参数（SSID/KEY）
echo.
netsh wlan stop hostednetwork
echo.
set ssid=
set /p ssid=请输入热点名称：
echo.
set key=
set /p key=请输入网络密码(8位以上)：
echo.
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key%
pause
goto main2
====================================
其几天测试wireshark内网抓包的时候，需要自己搭建wifi所以就做了一款利用笔记本自带的无线网卡做成wifi热点的工具。
复制以上代码，保存为bat即可。