With the UTL_FILE package, PL/SQL programs can read and write operating system text files. UTL_FILE provides a restricted version of operating system stream file I/O.
FOPEN
描述：打开一个文件，基本上在我们对文件进行读写动作之前都需要先执行这个function来打开文件先。
语法：
UTL_FILE.FOPEN ( location IN VARCHAR2,
filename IN VARCHAR2,
open_mode IN VARCHAR2,
max_linesize IN BINARY_INTEGER DEFAULT 1024) RETURN FILE_TYPE;
参数：location 略。
Filename 略。
open_mode 指明文件打开的模式。有如下几种：
■r –只读（文本）
■ w – 只写（本文）
■ a – 追加（文本）
■ rb – 只读（字节）
■ wb – 只写（字节）
■ ab – 追加（字节）
(注：当使用模式：a或者ab的时候，如果文件不存在，则会以write模式创建此文件)
max_linesize 指定文件文本每一行存放的最大字符数。
返回值：FOPEN返回一个接下来我们的程序将要使用到的文件的指针
FCLOSE
功能：关闭一个打开的文件。
语法：UTL_FILE.FCLOSE (file IN OUT FILE_TYPE);
参数：1. file->调用FOPEN或者FOPEN_NVCHAR返回的活动中的文件指针。
注意事项：当FCLOSE执行的时候，如果还有缓冲数据没有及时写入到文件中，
那么程序就会raise一个异常：WRITE_ERROR。可以在PUT_LINE的时候加上参数autoflush => TRUE；或者在每次PUT之后执行：FFLUSH。
FCLOSE_ALL
功能：此procedure将会关闭本次session所有打开的文件。它用来紧急情况的清理功能，例如当PL/SQL程序在EXCEPTION部分退出时。
语法：UTL_FILE.FCLOSE_ALL;
注意事项：FCLOSE_ALL不会修改所打开的文件的状态，也就是说执行了FCLOSE_ALL后，再用IS_OPEN去检测文件，结果还是打开状态，
但是之后，这些文件任然是不能去read或者write的。而FCLOSE执行后，相关的文件则完全关闭了
FCOPY
功能：此procedure复制一个文件的连续部分内容或者全部内容到一个新创建的文件。
如果参数start_line和end_line省略的话，默认地会复制整个文件。此操作会将源文件以read模式打开，将目标文件以write模式打开。
语法：
UTL_FILE.FCOPY ( src_location IN VARCHAR2,
src_filename IN VARCHAR2,
dest_location IN VARCHAR2,
dest_filename IN VARCHAR2,
start_line IN BINARY_INTEGER DEFAULT 1,
end_line IN BINARY_INTEGER DEFAULT NULL);
参数：src_location来源文件的目录名。取值来源是视图ALL_DIRECTORIES的DIRECTORY_NAME；
src_filename 将要被复制的来源文件
dest_location 被创建的目标文件存放的目录名。
dest_filename 从来源文件创建的目标文件。
start_line 要复制的内容起始行号，默认为1，表示从第一行开始复制。
end_line 要复制的内容的终止行号，默认NULL，表示文件的末尾。
FFLUSH
描述：FFLUSH强制将缓冲的数据写入文件。因为通常待写入文件的数据都是都在缓冲存储位置。当有必要去read一个任然处于打开状态的文件时，
FFLUSH就起作用了，例如在调试程序中，可以将调试的消息及时冲到文件中，已便于我们马上就能read这些内容。
语法：
UTL_FILE.FFLUSH (file IN FILE_TYPE);
FGETATTR
描述：FGETATTR读取磁盘上的文件并返回文件的属性。
语法：UTL_FILE.FGETATTR( location IN VARCHAR2,
filename IN VARCHAR2,
fexists OUT BOOLEAN,
file_length OUT NUMBER,
block_size OUT BINARY_INTEGER);
参数：location 此处略去X个字。
filename此处略去X个字。
fexists 返回的属性1：文件是否存在
file_length 返回的属性2：文件字节长度，如果文件不存在，则返回NULL。
block_size 文件系统块的字节大小。
FGETPOS
描述：此函数返回一个文件中当前的偏移位置。
语法：
UTL_FILE.FGETPOS (file IN FILE_TYPE) RETURN PLS_INTEGER;
注意事项：如果file没有打开，则会抛出异常
FREMOVE
描述：此procedure在你有充足的权限之下，删除一个磁盘上的文件。
语法：
UTL_FILE.FREMOVE ( location IN VARCHAR2,
filename IN VARCHAR2);
FRENAME
描述：此procedure将一个存在的文件重命名，类似unix命令：mv
语法：
UTL_FILE.FRENAME ( src_location IN VARCHAR2,
src_filename IN VARCHAR2,
dest_location IN VARCHAR2,
dest_filename IN VARCHAR2,
overwrite IN BOOLEAN DEFAULT FALSE);
GET_LINE
描述：此procedure从一个打开的文件中读取一行文本，直到遇到换行符。
语法：
UTL_FILE.GET_LINE ( file IN FILE_TYPE,
buffer OUT VARCHAR2,
len IN PLS_INTEGER DEFAULT NULL);
参数：len 从文本中读取一次的长度，默认是null，oracle就取FOPEN时的max_linesieze。
IS_OPEN
描述：顾名思义。
语法：UTL_FILE.IS_OPEN (file IN FILE_TYPE) RETURN BOOLEAN;
1.PUT
描述：PUT写入内容到文件中。（每写一次，不带换行符）
语法：UTL_FILE.PUT (file IN FILE_TYPE, buffer IN VARCHAR2);
PUT_LINE
描述：PUT_LINE写入内容到文件中。（每写一次，末尾都加一个换行符）
语法：
UTL_FILE.PUT_LINE ( file IN FILE_TYPE,
buffer IN VARCHAR2,
autoflush IN BOOLEAN DEFAULT FALSE);
PUTF
描述： 写入格式化的内容到文件中。好比C语言的printf()
语法：
UTL_FILE.PUTF ( file IN FILE_TYPE,
format IN VARCHAR2,
[arg1 IN VARCHAR2 DEFAULT NULL,
. . .
arg5 IN VARCHAR2 DEFAULT NULL]);
参数：format 包含格式化字符[\n，%s]的内容。
\n：代表一个换行符。
%s：用arg1~5的值去代替。
做一个例子如下：
CREATE OR REPLACE PROCEDURE SQL_TO_CSV
(
P_QUERY IN VARCHAR2, -- PLSQL文
P_DIR IN VARCHAR2, -- 导出的文件放置目录
P_FILENAME IN VARCHAR2 -- CSV名
)
IS
L_OUTPUT UTL_FILE.FILE_TYPE;
L_THECURSOR INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
L_COLUMNVALUE VARCHAR2(4000);
L_STATUS INTEGER;
L_COLCNT NUMBER := 0;
L_SEPARATOR VARCHAR2(1);
L_DESCTBL DBMS_SQL.DESC_TAB;
P_MAX_LINESIZE NUMBER := 32000;
BEGIN
--OPEN FILE
L_OUTPUT := UTL_FILE.FOPEN(P_DIR, P_FILENAME, 'A', P_MAX_LINESIZE);
--DEFINE DATE FORMAT
EXECUTE IMMEDIATE 'ALTER SESSION SET NLS_DATE_FORMAT=''YYYY-MM-DD HH24:MI:SS''';
--OPEN CURSOR
DBMS_SQL.PARSE( L_THECURSOR, P_QUERY, DBMS_SQL.NATIVE );
DBMS_SQL.DESCRIBE_COLUMNS( L_THECURSOR, L_COLCNT, L_DESCTBL );
--DUMP TABLE COLUMN NAM
FOR I IN 1 .. L_COLCNT LOOP
UTL_FILE.PUT( L_OUTPUT, L_SEPARATOR || '”' || L_DESCTBL(I).COL_NAME || '”' );
DBMS_SQL.DEFINE_COLUMN( L_THECURSOR, I, L_COLUMNVALUE, 4000 );
L_SEPARATOR := ',';
END LOOP;
UTL_FILE.NEW_LINE( L_OUTPUT );
--EXECUTE THE QUERY STATEMENT
L_STATUS := DBMS_SQL.EXECUTE(L_THECURSOR);
--DUMP TABLE COLUMN VALUE
WHILE ( DBMS_SQL.FETCH_ROWS(L_THECURSOR) > 0 ) LOOP
L_SEPARATOR := '';
FOR I IN 1 .. L_COLCNT LOOP
DBMS_SQL.COLUMN_VALUE( L_THECURSOR, I, L_COLUMNVALUE );
UTL_FILE.PUT( L_OUTPUT, L_SEPARATOR || '”' ||
TRIM(BOTH ' ' FROM REPLACE(L_COLUMNVALUE,'”','””')) || '”');
L_SEPARATOR := ',';
END LOOP;
UTL_FILE.NEW_LINE( L_OUTPUT );
END LOOP;
--CLOSE CURSOR
DBMS_SQL.CLOSE_CURSOR(L_THECURSOR);
--CLOSE FILE
UTL_FILE.FCLOSE( L_OUTPUT );
EXCEPTION
WHEN OTHERS THEN
RAISE;
END;
/
-- 创建存放文件的目录
CREATE OR REPLACE DIRECTORY MYDIR AS 'C:\';
create table t as select * from dba_users;
-- 执行块
begin
sql_to_csv('select * from T ','MYDIR','EXAMPLE2.CSV');
dbms_lock.sleep(10) ;
sql_to_csv('select * from T ','MYDIR','EXAMPLE3.CSV');
end;
/